Idiomatic Perl: Counting the Number of Times a Character Occurs in a String

From time to time you may want to count the number of occurrences of a character inside a string. You could loop from the beginning of the string to the end:

my $s = "Testing one two three.";

my $m = 0;
for (my $i = 0; $i < length($s); $i++) {
  $m++ if (substr($s, $i, 1) eq 'e');
}

Ugly. This is going to take all day with all those calls to substr.* You could split the string. There's a special split pattern // that divides the input string into characters. So perhaps:

my $n = 0;
for (split //, $s) {
  $n++ if $_ eq 'e';
}

Maybe this doesn't seem quite right to you yet. There must be a shorter way to do this in Perl, right? Yes. The tr/// (transliterate characters) operator can count characters for you. The tr/// operator returns the number of characters it changed. For example:

my $example = "Mixed Case";
my $changed = $example =~ tr/a-z/A-Z/;  # make everything uppercase
print $changed, "\n";  # 9

The value returned from tr/// above is 9, which is the number of characters changed to uppercase. Armed with this knowledge, you might think of:

my $c = $example =~ tr/e/e/;  # change 'e' to 'e' ...

which will work just fine. This is perfectly reasonable, but there's a shortcut. If you omit the second argument to tr///, no characters are changed, but tr/// still returns a count of the character(s) in its first argument.

my $c = $example =~ tr/e//;  # counts the number of 'e' just as above

my $c_lower = $example =~ tr/a-z//; # counts lowercase letters in $example

tr/// is so smart, in fact, that it knows when you aren't changing the string, meaning that you can write things like this:

my $count_ignore_case = lc($example) =~ tr/t//;

Normally, tr/// requires a modifiable value, but if it won't be making changes, you can supply a constant argument like a result from an expression.

-joseph

*Not really, but ouch.